extends TouchItemList
class_name Database

const DATABASE_FILE_PATH: String = "user://database.json"
const DATABASE_FILE_VERSION: int = 1

var db: Array
var selected_idx: int
var staged_idx: int

onready var stage			:= get_node("/root/main/stage") as Stage
onready var delete_button	:= get_node("actions/delete") as Button
onready var edit_button		:= get_node("actions/edit") as Button
onready var add_button		:= get_node("actions/add") as Button
onready var popup			:= get_node("/root/main/popup") as ModalPopup
onready var dialog			:= get_node("/root/main/dialog") as Dialog

func _init():
	selected_idx = -1
	staged_idx = -1
	load_database()


func _ready():
	self.connect("item_selected", self, "item_selected")
	self.connect("nothing_selected", self, "clear_selection")
	
	delete_button.connect("pressed", self, "delete_action")
	edit_button.connect("pressed", self, "edit_action")
	add_button.connect("pressed", self, "add_action")	
	
	stage.connect("save", self, "save_stage")
	stage.connect("discard", self, "discard_stage")
	
	for it in db:
		self.add_item(get_entry_view(it))
	
	clear_selection()


func get_entry_view(database_entry: Dictionary) -> String:
	return "%6s | %6s | %s" % [database_entry.process_id, database_entry.surgery_id, DatabaseEntry.get_entry_date(database_entry)]


func item_selected(index: int):
	selected_idx = index
	set_buttons_active(true)


func clear_selection():
	selected_idx = -1
	unselect_all()
	set_buttons_active(false)


func set_buttons_active(active: bool):
	(get_node("actions/delete") as Button).disabled = !active
	(get_node("actions/edit") as Button).disabled = !active


func delete_action():
	if selected_idx < 0:
		return
	
	dialog.setup("The entry with process ID '%s' will be deleted from the database." % db[selected_idx].process_id, "Delete", "No")
	dialog.connect("accepted", self, "delete_action_confirmed")
	popup.open_popup("Delete entry?", dialog)


func delete_action_confirmed():
	db.remove(selected_idx)
	self.remove_item(selected_idx)
	selected_idx = -1
	save_database()
	clear_selection()


func edit_action():
	if selected_idx < 0:
		return
	
	staged_idx = selected_idx
	self.visible = false
	stage.visible = true
	var staged := (db[staged_idx] as Dictionary).duplicate(true)
	stage.set_stage(staged, "Entry #%d" % (staged_idx+1))


func add_action():
	self.visible = false
	stage.visible = true
	var staged := DatabaseEntry.instance_entry()
	stage.set_stage(staged, "New entry")


func save_stage(entry: Dictionary):
	if DatabaseEntry.is_valid_entry(entry) == false:
		printerr("INVALID ENTRY RECEIVED")
		return # @DAM Deal with this.
	
	var next_selected_idx: int
	if staged_idx >= 0:
		db[staged_idx] = entry
		next_selected_idx = staged_idx
	else:
		db.append(entry)
		self.add_item(get_entry_view(entry))
		next_selected_idx = db.size() - 1
	
	select(next_selected_idx)
	emit_signal("item_selected", next_selected_idx) # Calling "select" does not trigger the "item_selected" signal.
	set_item_text(selected_idx, get_entry_view(db[selected_idx]))
	ensure_current_is_visible()
	
	save_database()
	
	staged_idx = -1
	self.visible = true
	grab_focus()


func discard_stage():
	staged_idx = -1
	self.visible = true
	grab_focus()


func load_database(file_path: String = DATABASE_FILE_PATH):
	var file := File.new()
	file.open(file_path, File.READ_WRITE)
	var file_content = file.get_as_text()
	file.close()
	var parse_result = JSON.parse(file_content)
	
	if parse_result.error != OK || typeof(parse_result.result) != TYPE_DICTIONARY:
		push_error("Failed to parse database file: '%s'.")
		return
	
	if parse_result.result["version"] != DATABASE_FILE_VERSION:
		push_error("Invalid database file version '%s', expected '%s'." % DATABASE_FILE_VERSION)
		return
	
	if typeof(parse_result.result["database"]) != TYPE_ARRAY:
		push_error("Failed to load database file contents.")
		return
	
	db = parse_result.result["database"]
	
	# The JSON specification does not define integer or float types, but only a number type.
	# Therefore, converting a Variant to JSON text will convert all numerical values to float types.
	# Thus, we cast all integer values once we load them.
	for it in db:
		it.date_year = int(it.date_year)
		it.date_month = int(it.date_month)
		it.date_day = int(it.date_day)


func save_database(file_path: String = DATABASE_FILE_PATH):
	var database_file := {
		"version": DATABASE_FILE_VERSION,
		"database": db,
	}
	var indentation_char := "" if file_path == DATABASE_FILE_PATH else "\t"
	var file_content := JSON.print(database_file, indentation_char)
	
	var file := File.new()
	file.open(file_path, File.WRITE)
	file.store_string(file_content)
	file.close()


static func import_database(file_path: String) -> Array:
	var result: Array
	var file := File.new()
	file.open(file_path, File.READ_WRITE)
	var headers := file.get_csv_line()
	while file.get_position() < file.get_len():
		var csv_entry := file.get_csv_line()
		var entry = DatabaseEntry.instance_entry()
		for idx in headers.size():
			var field_name := headers[idx]
			var field_value := csv_entry[idx]
			match field_name:
				"date":
					DatabaseEntry.set_entry_date(entry, field_value)
				"date_year", "date_month", "date_day":
					entry[field_name] = int(field_value)
				"is_urgency":
					entry[field_name] = true if field_value.strip_edges().to_lower() == "true" else false
				_:
					if DatabaseEntry.ENTRY_PROTOTYPE.has(field_name):
						entry[field_name] = field_value
		if DatabaseEntry.is_valid_entry(entry):
			result.append(entry)
	file.close()
	return result


static func export_database(file_path: String, database: Array = db):
	var file := File.new()
	file.open(file_path, File.WRITE)
	var header := PoolStringArray(DatabaseEntry.ENTRY_PROTOTYPE.keys())
	file.store_csv_line(header)
	for it in database:
		# @DAM This approach depends on the order the dictionary fields are created.
		file.store_csv_line(it.values())
	file.close()


func clear_database():
	clear_selection()
	self.clear()
	db.resize(0)


func fake_database():
	clear_database()
	for idx in range(500):
		var today := OS.get_date(true)
		var date_year = today.year + int(float(idx) / 30.0 / 12)
		var date_month = 1 + int(float(idx) / 30.0) % 12
		var date_day = 1 + (idx % 30)
		var fake_entry = DatabaseEntry.instance_entry({
			"process_id": "%06d" % idx,
			"surgery_id": "s%05d" % idx,
			"date_year": date_year,
			"date_month": date_month,
			"date_day": date_day,
		})
		db.append(fake_entry)
		self.add_item(get_entry_view(fake_entry))