extends TouchItemList
class_name Database

const DATABASE_FILE_PATH: String = "user://database.csv"

var db: Array
var selected_idx: int
var staged_idx: int

onready var confirm_action	:= get_node("/root/main/confirm_action") as ConfirmationDialog
onready var stage			:= get_node("/root/main/stage") as Stage
onready var delete_button	:= get_node("actions/delete") as Button
onready var edit_button		:= get_node("actions/edit") as Button
onready var add_button		:= get_node("actions/add") as Button


func _init():
	selected_idx = -1
	staged_idx = -1
	load_database()
	store_database() # @DAM Only for testing.


func _ready():
	self.connect("item_selected", self, "item_selected")
	self.connect("nothing_selected", self, "clear_selection")
	
	delete_button.connect("pressed", self, "delete_action")
	edit_button.connect("pressed", self, "edit_action")
	add_button.connect("pressed", self, "add_action")	
	
	stage.connect("save", self, "save_stage")
	stage.connect("discard", self, "discard_stage")
	
	for it in db:
		self.add_item(get_entry_view(it))


func _notification(what: int):
	# @DAM This code should be moved into the main.gd which should check which node was currently
	# active and above, and send the signal there.
	if visible == false || has_focus() == false:
		return
		
	if what == MainLoop.NOTIFICATION_WM_GO_BACK_REQUEST:
		if selected_idx >= 0:
			clear_selection()
		else:
			get_tree().quit()


func get_entry_view(database_entry: Dictionary) -> String:
	return "%6s | %6s | %s" % [database_entry.process_id, database_entry.surgery_id, DatabaseEntry.get_entry_date(database_entry)]


func item_selected(index: int):
	selected_idx = index


func clear_selection():
	selected_idx = -1
	unselect_all()


func delete_action():
	if selected_idx < 0:
		return
	
	confirm_action.window_title = "DELETE ENTRY"
	confirm_action.dialog_text = "Do you want to delete entry with process ID '%s' from the database?" % db[selected_idx].process_id
	confirm_action.connect("confirmed", self, "delete_action_confirmed", [], CONNECT_ONESHOT)
	confirm_action.show_modal(true)


func delete_action_confirmed():
	db.remove(selected_idx)
	self.remove_item(selected_idx)
	selected_idx = -1
	store_database()


func edit_action():
	if selected_idx < 0:
		return
	
	staged_idx = selected_idx
	self.visible = false
	stage.visible = true
	var staged := (db[staged_idx] as Dictionary).duplicate(true)
	stage.set_stage(staged)


func add_action():
	self.visible = false
	stage.visible = true
	var staged := DatabaseEntry.instance_entry()
	stage.set_stage(staged)


func save_stage(entry: Dictionary):
	if DatabaseEntry.is_valid_entry(entry) == false:
		printerr("INVALID ENTRY RECEIVED")
		return # @DAM Deal with this.
	
	var next_selected_idx: int
	if staged_idx >= 0:
		db[staged_idx] = entry
		next_selected_idx = staged_idx
	else:
		db.append(entry)
		add_item(get_entry_view(entry))
		next_selected_idx = db.size() - 1
	
	select(next_selected_idx)
	emit_signal("item_selected", next_selected_idx) # Calling "select" does not trigger the "item_selected" signal.
	set_item_text(selected_idx, get_entry_view(db[selected_idx]))
	ensure_current_is_visible()
	
	store_database()
	
	staged_idx = -1
	self.visible = true
	grab_focus()


func discard_stage():
	staged_idx = -1
	self.visible = true
	grab_focus()


func load_database(file_path: String = DATABASE_FILE_PATH):
	var file := File.new()
	file.open(file_path, File.READ_WRITE)
	var headers: PoolStringArray
	var is_first_line := true
	while file.get_position() < file.get_len():
		var csv_entry := file.get_csv_line()
		if is_first_line:
			is_first_line = false
			headers = csv_entry
			continue
		var entry = DatabaseEntry.instance_entry()
		for idx in headers.size():
			var field_name := headers[idx]
			var field_value := csv_entry[idx]
			match field_name:
				"date_year", "date_month", "date_day":
					entry[field_name] = int(field_value)
				"is_urgency":
					entry[field_name] = true if field_value.strip_edges().to_lower() == "true" else false
				_:
					entry[field_name] = field_value
		db.append(entry)
	file.close()


func store_database(file_path: String = DATABASE_FILE_PATH):
	var file := File.new()
	file.open(file_path, File.WRITE)
	var header := PoolStringArray(DatabaseEntry.ENTRY_PROTOTYPE.keys())
	file.store_csv_line(header)
	for it in db:
		# @DAM This approach depends on the order the dictionary fields are created.
		file.store_csv_line(it.values())
	file.close()


func clear_database(save_changes: bool = false):
	clear_selection()
	self.clear()
	db.resize(0)
	if save_changes:
		store_database()


func fake_database(save_changes: bool = false):
	clear_database()
	for idx in range(500):
		var today := OS.get_date(true)
		var date_year = today.year + int(float(idx) / 30.0 / 12)
		var date_month = 1 + int(float(idx) / 30.0) % 12
		var date_day = 1 + (idx % 30)
		var fake_entry = DatabaseEntry.instance_entry({
			"process_id": "%06d" % idx,
			"surgery_id": "s%05d" % idx,
			"date_year": date_year,
			"date_month": date_month,
			"date_day": date_day,
		})
		db.append(fake_entry)
		self.add_item(get_entry_view(fake_entry))
	if save_changes:
		store_database()